NixOS und Forgejo auf einem manitu-vServer
Heute hatte Codeberg Probleme mit DNS, und für mich war das der Anstoß, mich nach Alternativen umzusehen. Ich wollte mal sehen, was Forgejo so zu bieten hat.
Die erste Entscheidung war, dass ich mein Git getrennt von meinem Server halten möchte: Mein Server zieht seine Konfiguration aus Git (so mache ich das) und baut dann seinen aktuellen Stand. Wenn sich da nun ein Fehler einschleicht, ist nicht nur der Server weg, sondern auch die Konfiguration. Deshalb wollte ich eine kleine Maschine nur für Forgejo haben.
Bisher läuft alles bei mir über Hetzner, aber gerade sieht es bei den kleineren Maschinen eher dünn aus. Also habe ich einen Blick auf manitu geworfen. Ich hatte mitbekommen, dass 0x17 da schon erfolgreich NixOS deployt hat und inzwischen ein paar Maschinen dort laufen hat. Preislich ist es wesentlich besser als Hetzner, und daher habe ich das Experiment gewagt.
Die Maschine ansehen
Ich nehme den vServer M und wähle beim Bestellen das Image Debian 13. Bevor ich NixOS installiere, prüfe ich vier Dinge:
ls /sys/firmware/efi
lsblk -f
cat /etc/netplan/*.yaml
cat /proc/sys/kernel/kexec_load_disabledJeder Befehl beantwortet eine Frage, die ich für die NixOS-Konfiguration brauche. Ob es /sys/firmware/efi gibt, zeigt, ob der Server per UEFI oder per BIOS startet, und davon hängen Bootloader und Partitionierung ab. lsblk -f verrät den Gerätenamen der Platte für disko, die Netplan-Datei die Netzwerkeinstellungen, die ich in NixOS nachbauen muss. Und kexec_load_disabled entscheidet, ob nixos-anywhere den Installer per kexec starten kann.
Bei mir startet der Server per BIOS, /sys/firmware/efi gibt es nicht. Die Platte heißt /dev/vda (virtio). Das Netzwerk ist statisch konfiguriert, ohne DHCP, und das IPv6-Gateway liegt außerhalb des eigenen /64, die Route braucht deshalb on-link. kexec ist erlaubt, damit läuft nixos-anywhere.
Platte
Wegen des BIOS-Starts braucht die GPT-Platte eine BIOS-Boot-Partition (EF02). Dazu kommt eine Root-Partition, /boot liegt darauf:
disko.devices.disk.main = {
type = "disk";
device = "/dev/vda";
content = {
type = "gpt";
partitions = {
boot = { size = "1M"; type = "EF02"; priority = 1; };
root = {
size = "100%";
content = {
type = "filesystem";
format = "ext4";
mountpoint = "/";
};
};
};
};
};GRUB kommt auf die Platte, und die virtio-Module gehören in die initrd:
boot.loader.grub = {
enable = true;
devices = lib.mkForce [ "/dev/vda" ];
};
boot.initrd.availableKernelModules = [
"virtio_pci" "virtio_blk" "virtio_scsi" "virtio_net"
];Netzwerk
Die Schnittstelle ordne ich über die MAC-Adresse zu, nicht über den Namen (im Debian-Image heißt sie ens3). Die Adressen sind Platzhalter:
networking = {
useDHCP = false;
useNetworkd = true;
nameservers = [ "203.0.113.53" "203.0.113.54" ];
};
systemd.network.networks."10-wan" = {
matchConfig.MACAddress = "aa:bb:cc:dd:ee:ff";
address = [ "203.0.113.10/22" "2001:db8:0:1::1/64" ];
routes = [
{ Gateway = "203.0.112.1"; }
{ Gateway = "2001:db8:0::1"; GatewayOnLink = true; }
];
networkConfig.IPv6AcceptRA = false;
};Installation
Ich installiere mit nixos-anywhere, wie schon bei Hetzner. Gebaut wird auf dem Server (--build-on remote), weil mein Mac kein x86-Linux bauen kann. Den SSH-Host-Key erzeuge ich vorher lokal und gebe ihn mit --extra-files mit, damit sich die Secrets (sops-nix) beim ersten Start gleich entschlüsseln lassen.
Die Verbindung zum Server war bei mir wackelig: Ping und HTTPS gingen, aber Port 22 lief immer wieder in den Timeout, meist schon beim Aufbau. Eine Ursache habe ich nicht gefunden, fail2ban ist es nicht, und auch nach der Installation brauchen Deploys und git push manchmal mehrere Versuche. Geholfen hat, alle Aufrufe von nixos-anywhere über eine einzige SSH-Verbindung laufen zu lassen (ControlMaster, ControlPersist) und großzügige Keepalives zu setzen (ServerAlive…). Damit lief alles deutlich stabiler, und die Installation kam durch.
Über HostName=… setze ich die Adresse, ohne meine ~/.ssh/config anzufassen. server ist nur ein Platzhalter. Ich nehme im Beispiel IPv6, weil IPv4 bei mir zeitweise nicht durchkam:
CP="$TMPDIR/na.sock"
nix run github:nix-community/nixos-anywhere -- \
--flake ".#server" --build-on remote \
--extra-files extra \
--ssh-option HostName=2001:db8:0:1::1 \
--ssh-option ControlMaster=auto \
--ssh-option "ControlPath=$CP" \
--ssh-option ControlPersist=30m \
--ssh-option ServerAliveInterval=30 \
--ssh-option ServerAliveCountMax=30 \
root@serverNach dem Wechsel in den Installer (kexec) war die alte Verbindung tot, mein Terminal merkte das aber nicht und wartete weiter, obwohl der Server längst im Installer stand. Ich habe abgebrochen und mit --phases disko,install,reboot neu gestartet, dann entfällt kexec. disko formatiert die Platte dabei neu, was auf einem frischen Server nicht stört.
Der erfolgreiche Lauf hat von der Partitionierung bis zum Neustart knapp vier Minuten gedauert. Danach kam der Server mit dem vorher erzeugten Host-Key hoch, und systemctl --failed war leer.
Forgejo
Forgejo kommt aus dem NixOS-Modul services.forgejo, mit Postgres über den Unix-Socket und nginx davor. Der Kern der Konfiguration:
services.forgejo = {
enable = true;
database = {
type = "postgres";
createDatabase = true;
};
settings = {
server = {
DOMAIN = "git.example.org";
ROOT_URL = "https://git.example.org/";
HTTP_ADDR = "127.0.0.1";
HTTP_PORT = 3000;
};
service = {
DISABLE_REGISTRATION = true;
};
};
};DISABLE_REGISTRATION schließt die Registrierung.
Git über SSH läuft über den normalen sshd auf Port 22. Forgejo trägt die Schlüssel in die authorized_keys des Benutzers forgejo ein, und ein Match-Block nimmt dem Konto Weiterleitungen und TTY:
services.openssh.extraConfig = ''
Match User forgejo
AllowAgentForwarding no
AllowTcpForwarding no
X11Forwarding no
PermitTTY no
'';Davor sitzt nginx mit forceSSL und enableACME, ohne E-Mail-Adresse, damit meine nicht bei Let's Encrypt landet. Deployt habe ich vom Mac aus mit nixos-rebuild --target-host und ähnlichen SSH-Einstellungen wie bei der Installation (per NIX_SSHOPTS), gebaut wird auf dem Server.
Ohne Konto kommt man nicht hinein, also lege ich den Admin über die Kommandozeile an. forgejo ist dort nicht im PATH, weil das Modul das Paket nicht installiert, es muss in environment.systemPackages. Das Passwort erzeugt Forgejo selbst und zeigt es einmal an:
runuser -u forgejo -- env \
FORGEJO_WORK_DIR=/var/lib/forgejo \
FORGEJO_CUSTOM=/var/lib/forgejo/custom \
forgejo admin user create --admin \
--username <name> --email <mail> \
--random-password --must-change-password=falseAnderer Benutzer als forgejo
Ich wollte git@git.example.org: als Clone-URL, deshalb läuft Forgejo bei mir als Benutzer git. Das Modul legt Benutzer und Gruppe nur an, wenn sie forgejo heißen, also muss users.users.git selbst definiert werden, sonst startet der Dienst nicht. Außerdem verlangt NixOS bei einer selbst angelegten Datenbank, dass Name und Benutzer gleich sind. In services.forgejo kommt dazu:
user = "git";
group = "git";
database.name = "git";
database.user = "git";Dazu der Benutzer selbst:
users.users.git = {
isSystemUser = true;
group = "git";
home = config.services.forgejo.stateDir;
useDefaultShell = true;
};
users.groups.git = { };Beim Match-Block und bei runuser steht dann git statt forgejo.
Spiegeln nach Codeberg
Ausgewählte Repos, darunter dieses Blog, spiegelt Forgejo per Push-Mirror nach Codeberg, gepusht wird nur noch zu Forgejo. Eingerichtet wird das pro Repo unter „Settings“ > „Repository“ > „Mirror Settings“: Ich trage die Codeberg-URL ein und wähle unter „Authorization“ die SSH-Authentifizierung. Forgejo erzeugt dann ein Schlüsselpaar, den öffentlichen Teil hinterlege ich bei Codeberg als Deploy-Key mit Schreibrecht, so braucht es keinen Token. Dazu aktiviere ich „Sync when new commits are pushed“, das Intervall steht bei acht Stunden. „Synchronize Now“ stößt den ersten Abgleich an. Ein Push-Mirror überschreibt das Ziel per Force-Push, Änderungen direkt bei Codeberg gehen dabei verloren.
Ein Stolperstein bei der Migration: Sie hat refs/pull/* von Codeberg mitgebracht, und der Mirror scheiterte daran mit fail to run proc-receive hook, bis ich diese Refs entfernt habe.
Ein paar Projekte lasse ich vorerst bei Codeberg, den Rest ziehe ich schrittweise um. Nach den ersten Stunden mit meinem selbst gehosteten Forgejo bin ich sehr zufrieden: Da ich der einzige Nutzer bin, ist alles unfassbar schnell, und die Performance, die mich bei Codeberg zuletzt genervt hat, ist hier kein Thema. Trotzdem soll mein Code dort abrufbar bleiben, ich finde das Projekt weiterhin förderungswürdig.
Meine Infrastruktur und ein Großteil meines Codes liegen jetzt auf meinem manitu-Server, vom nächsten Ausfall von Codeberg bekomme ich hoffentlich nichts mehr mit.